mymuseum-visitapp/android/app/build.gradle

plugins {
    id "com.android.application"
    id "kotlin-android"
    // The Flutter Gradle Plugin must be applied after the Android and Kotlin Gradle plugins.
    id "dev.flutter.flutter-gradle-plugin"
    id "com.google.gms.google-services"
}

def localProperties = new Properties()
def localPropertiesFile = rootProject.file('local.properties')
if (localPropertiesFile.exists()) {
    localPropertiesFile.withReader('UTF-8') { reader ->
        localProperties.load(reader)
    }
}

def keystoreProperties = new Properties()
def keystorePropertiesFile = rootProject.file('key.properties')
if (keystorePropertiesFile.exists()) {
    keystoreProperties.load(new FileInputStream(keystorePropertiesFile))
}

/*def flutterRoot = localProperties.getProperty('flutter.sdk')
if (flutterRoot == null) {
    throw new GradleException("Flutter SDK not found. Define location with flutter.sdk in the local.properties file.")
}*/

def flutterVersionCode = localProperties.getProperty('flutter.versionCode')
if (flutterVersionCode == null) {
    flutterVersionCode = '1'
}

def flutterVersionName = localProperties.getProperty('flutter.versionName')
if (flutterVersionName == null) {
    flutterVersionName = '1.0'
}

/*apply plugin: 'com.android.application'
apply plugin: 'kotlin-android'
apply from: "$flutterRoot/packages/flutter_tools/gradle/flutter.gradle"*/

android {
    namespace = "be.unov.mymuseum.fortsaintheribert"
    compileSdkVersion 36
    ndkVersion "28.2.13676358"

    compileOptions {
        sourceCompatibility JavaVersion.VERSION_1_8
        targetCompatibility JavaVersion.VERSION_1_8
        coreLibraryDesugaringEnabled true
    }

    packagingOptions {
        pickFirst 'lib/arm64-v8a/libc++_shared.so'
        pickFirst 'lib/x86_64/libc++_shared.so'
        pickFirst 'lib/x86/libc++_shared.so'
        pickFirst 'lib/armeabi-v7a/libc++_shared.so'
    }

    kotlinOptions {
        jvmTarget = '1.8'
    }

    sourceSets {
        main.java.srcDirs += 'src/main/kotlin'
    }

    defaultConfig {
        minSdkVersion 29  // meta_wearables SDK requires API 29+
        targetSdkVersion flutter.targetSdkVersion
        versionCode flutterVersionCode.toInteger()
        versionName flutterVersionName
        multiDexEnabled true
        manifestPlaceholders = [
            mwdatCallbackScheme: "mwdat-myinfomate",
            applicationName: "io.flutter.app.FlutterApplication"
        ]
    }

    flavorDimensions "client"

    productFlavors {
        dev {
            dimension "client"
            applicationId "be.unov.myinfomate.test"
            resValue "string", "app_name", "MyMuseum Dev"
            manifestPlaceholders = [
                mwdatCallbackScheme: "mwdat-myinfomate-dev",
                applicationName: "io.flutter.app.FlutterApplication"
            ]
        }
        mdlf {
            dimension "client"
            applicationId "be.unov.mymuseum.mdlf"
            resValue "string", "app_name", "MDLF"
            manifestPlaceholders = [
                mwdatCallbackScheme: "mwdat-mymuseum-mdlf",
                applicationName: "io.flutter.app.FlutterApplication"
            ]
        }
        fortsaintheribert {
            dimension "client"
            applicationId "be.unov.mymuseum.fortsaintheribert"
            resValue "string", "app_name", "Fort Saint-Héribert"
            manifestPlaceholders = [
                mwdatCallbackScheme: "mwdat-mymuseum-fortsaintheribert",
                applicationName: "io.flutter.app.FlutterApplication"
            ]
        }
    }

    signingConfigs {
        release {
            keyAlias keystoreProperties['keyAlias']
            keyPassword keystoreProperties['keyPassword']
            storeFile keystoreProperties['storeFile'] ? file(keystoreProperties['storeFile']) : null
            storePassword keystoreProperties['storePassword']
        }
    }

    buildTypes {
        release {
            // Signing with the debug keys for now, so `flutter run --release` works.
            signingConfig signingConfigs.release
            minifyEnabled true
            shrinkResources true
            debuggable false
        }
    }
}

flutter {
    source '../..'
}

dependencies {
    coreLibraryDesugaring 'com.android.tools:desugar_jdk_libs:2.0.4'
    implementation 'org.tensorflow:tensorflow-lite:2.12.0'
    implementation 'com.microsoft.onnxruntime:onnxruntime-android:1.16.0'
}