/*buildscript {
    ext.kotlin_version = '1.9.0'
    repositories {
        google()
        mavenCentral()
    }

    dependencies {
        classpath 'com.android.tools.build:gradle:7.2.0'
        classpath "org.jetbrains.kotlin:kotlin-gradle-plugin:$kotlin_version"
    }
}*/

def rootLocalProps = new Properties()
def rootLocalPropsFile = rootProject.file('local.properties')
if (rootLocalPropsFile.exists()) {
    rootLocalPropsFile.withReader('UTF-8') { reader -> rootLocalProps.load(reader) }
}

allprojects {
    repositories {
        google()
        mavenCentral()
        maven {
            url = uri("https://maven.pkg.github.com/facebook/meta-wearables-dat-android")
            credentials {
                username = "x-access-token"
                password = System.getenv("GITHUB_TOKEN")
                    ?: rootLocalProps.getProperty("github_token")
                    ?: ""
            }
        }
    }
}

rootProject.buildDir = '../build'
subprojects {
    project.buildDir = "${rootProject.buildDir}/${project.name}"
}
subprojects {
    project.evaluationDependsOn(':app')
}

// Fix pour les packages Flutter qui n'ont pas de namespace (beacon_scanner v0.0.4, etc.)
subprojects {
    plugins.withId("com.android.library") {
        if (!android.namespace) {
            def manifestFile = android.sourceSets.main.manifest.srcFile
            if (manifestFile?.exists()) {
                def packageName = new groovy.xml.XmlSlurper()
                    .parse(manifestFile)['@package'].text()
                if (packageName) {
                    android.namespace = packageName
                }
            }
        }
    }
}

tasks.register("clean", Delete) {
    delete rootProject.buildDir
}